Merge pull request #821 from 1hitsong/ui-refresh/movie-library-list

Update Movie Library View

components/ItemGrid/GridItemSmall.brs

@@ -0,0 +1,42 @@
+sub init()
+    m.itemPoster = m.top.findNode("itemPoster")
+    m.posterText = m.top.findNode("posterText")
+    m.posterText.font.size = 30
+    m.backdrop = m.top.findNode("backdrop")
+
+    m.itemPoster.observeField("loadStatus", "onPosterLoadStatusChanged")
+
+    'Parent is MarkupGrid and it's parent is the ItemGrid
+    m.topParent = m.top.GetParent().GetParent()
+
+    'Get the imageDisplayMode for these grid items
+    if m.topParent.imageDisplayMode <> invalid
+        m.itemPoster.loadDisplayMode = m.topParent.imageDisplayMode
+    end if
+
+end sub
+
+sub itemContentChanged()
+    m.backdrop.blendColor = "#101010"
+
+    itemData = m.top.itemContent
+
+    if not isValid(itemData) then return
+
+    m.itemPoster.uri = itemData.PosterUrl
+    m.posterText.text = itemData.title
+
+    'If Poster not loaded, ensure "blue box" is shown until loaded
+    if m.itemPoster.loadStatus <> "ready"
+        m.backdrop.visible = true
+        m.posterText.visible = true
+    end if
+end sub
+
+'Hide backdrop and text when poster loaded
+sub onPosterLoadStatusChanged()
+    if m.itemPoster.loadStatus = "ready"
+        m.backdrop.visible = false
+        m.posterText.visible = false
+    end if
+end sub

components/ItemGrid/GridItemSmall.xml

@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="utf-8" ?>
+<component name="GridItemSmall" extends="Group">
+  <children>
+    <Poster id="backdrop" translation="[0,15]" width="230" height="320" loadDisplayMode="scaleToZoom" uri="pkg:/images/white.9.png" />
+    <Poster id="itemPoster" translation="[0,15]" width="230" height="320" loadDisplayMode="scaleToZoom" />
+    <Poster id="itemIcon" width="50" height="50" translation="[230,10]" />
+    <Label id="posterText" width="230" height="320" translation="[5,5]" horizAlign="center" vertAlign="center" ellipsizeOnBoundary="true" wrap="true" />
+  </children>
+  <interface>
+    <field id="itemContent" type="node" onChange="itemContentChanged" />
+    <field id="itemHasFocus" type="boolean" onChange="focusChanged" />
+  </interface>
+  <script type="text/brightscript" uri="GridItemSmall.brs" />
+  <script type="text/brightscript" uri="pkg:/source/utils/misc.brs" />
+  <script type="text/brightscript" uri="pkg:/source/utils/config.brs" />
+</component>

components/ItemGrid/LoadItemsTask2.brs

@@ -20,6 +20,16 @@ sub loadItems()
         sort_order = "Descending"
     end if
 
+    if m.top.ItemType = "LogoImage"
+        logoImageExists = api_API().items.headimageurlbyname(m.top.itemId, "logo")
+        if logoImageExists
+            m.top.content = [api_API().items.getimageurl(m.top.itemId, "logo", 0, { "maxHeight": 500, "maxWidth": 500, "quality": "90" })]
+        else
+            m.top.content = []
+        end if
+
+        return
+    end if
 
     params = {
         limit: m.top.limit,
@@ -117,7 +127,49 @@ sub loadItems()
             else if item.type = "Episode"
                 tmp = CreateObject("roSGNode", "TVEpisode")
             else if item.Type = "Genre"
-                tmp = CreateObject("roSGNode", "FolderData")
+                tmp = CreateObject("roSGNode", "ContentNode")
+                tmp.title = item.name
+
+                genreData = api_API().users.getitemsbyquery(get_setting("active_user"), {
+                    SortBy: "Random",
+                    SortOrder: "Ascending",
+                    IncludeItemTypes: "Movie",
+                    Recursive: true,
+                    Fields: "PrimaryImageAspectRatio,MediaSourceCount,BasicSyncInfo",
+                    ImageTypeLimit: 1,
+                    EnableImageTypes: "Primary",
+                    Limit: 6,
+                    GenreIds: item.id,
+                    EnableTotalRecordCount: false,
+                    ParentId: m.top.itemId
+                })
+
+                if genreData.Items.Count() > 5
+                    ' Add View All item to the start of the row
+                    row = tmp.createChild("FolderData")
+                    row.parentFolder = m.top.itemId
+                    genreMovieImage = api_API().items.getimageurl(item.id)
+                    row.title = item.name
+                    row.json = item
+                    row.FHDPOSTERURL = genreMovieImage
+                    row.HDPOSTERURL = genreMovieImage
+                    row.SDPOSTERURL = genreMovieImage
+                    row.type = "Folder"
+                end if
+
+                for each genreMovie in genreData.Items
+                    row = tmp.createChild("MovieData")
+
+                    genreMovieImage = api_API().items.getimageurl(genreMovie.id)
+                    row.title = genreMovie.name
+                    row.FHDPOSTERURL = genreMovieImage
+                    row.HDPOSTERURL = genreMovieImage
+                    row.SDPOSTERURL = genreMovieImage
+                    row.json = genreMovie
+                    row.id = genreMovie.id
+                    row.type = genreMovie.type
+                end for
+
             else if item.Type = "Studio"
                 tmp = CreateObject("roSGNode", "FolderData")
             else if item.Type = "MusicAlbum"
@@ -135,12 +187,16 @@ sub loadItems()
             else
                 print "[LoadItems] Unknown Type: " item.Type
             end if
+
             if tmp <> invalid
+                if item.Type <> "Genre"
                     tmp.parentFolder = m.top.itemId
                     tmp.json = item
                     if item.UserData <> invalid and item.UserData.isFavorite <> invalid
                         tmp.favorite = item.UserData.isFavorite
                     end if
+                end if
+
                 results.push(tmp)
             end if
         end for

components/ItemGrid/MovieLibraryView.brs

@@ -0,0 +1,790 @@
+sub setupNodes()
+    m.options = m.top.findNode("options")
+    m.itemGrid = m.top.findNode("itemGrid")
+    m.voiceBox = m.top.findNode("voiceBox")
+    m.backdrop = m.top.findNode("backdrop")
+    m.newBackdrop = m.top.findNode("backdropTransition")
+    m.emptyText = m.top.findNode("emptyText")
+    m.selectedMovieName = m.top.findNode("selectedMovieName")
+    m.selectedMovieOverview = m.top.findNode("selectedMovieOverview")
+    m.selectedMovieProductionYear = m.top.findNode("selectedMovieProductionYear")
+    m.selectedMovieOfficialRating = m.top.findNode("selectedMovieOfficialRating")
+    m.movieLogo = m.top.findNode("movieLogo")
+    m.swapAnimation = m.top.findNode("backroundSwapAnimation")
+    m.spinner = m.top.findNode("spinner")
+    m.Alpha = m.top.findNode("AlphaMenu")
+    m.AlphaSelected = m.top.findNode("AlphaSelected")
+    m.micButton = m.top.findNode("micButton")
+    m.micButtonText = m.top.findNode("micButtonText")
+    m.communityRatingGroup = m.top.findNode("communityRatingGroup")
+    m.criticRatingIcon = m.top.findNode("criticRatingIcon")
+    m.criticRatingGroup = m.top.findNode("criticRatingGroup")
+    m.overhang = m.top.getScene().findNode("overhang")
+    m.genreList = m.top.findNode("genrelist")
+    m.infoGroup = m.top.findNode("infoGroup")
+end sub
+
+sub init()
+    setupNodes()
+
+    m.overhang.isVisible = false
+
+    m.showItemCount = get_user_setting("itemgrid.showItemCount") = "true"
+
+    m.swapAnimation.observeField("state", "swapDone")
+
+    m.loadedRows = 0
+    m.loadedItems = 0
+
+    m.data = CreateObject("roSGNode", "ContentNode")
+
+    m.itemGrid.content = m.data
+
+    m.genreData = CreateObject("roSGNode", "ContentNode")
+    m.genreList.observeField("itemSelected", "onGenreItemSelected")
+    m.genreList.content = m.genreData
+
+    m.itemGrid.observeField("itemFocused", "onItemFocused")
+    m.itemGrid.observeField("itemSelected", "onItemSelected")
+    m.itemGrid.observeField("alphaSelected", "onItemalphaSelected")
+
+    'Voice filter setup
+    m.voiceBox.voiceEnabled = true
+    m.voiceBox.active = true
+    m.voiceBox.observeField("text", "onvoiceFilter")
+    'set voice help text
+    m.voiceBox.hintText = tr("Use voice remote to search")
+
+    'backdrop
+    m.newBackdrop.observeField("loadStatus", "newBGLoaded")
+
+    'Background Image Queued for loading
+    m.queuedBGUri = ""
+
+    'Item sort - maybe load defaults from user prefs?
+    m.sortField = "SortName"
+    m.sortAscending = true
+
+    m.filter = "All"
+    m.favorite = "Favorite"
+
+    m.loadItemsTask = createObject("roSGNode", "LoadItemsTask2")
+    m.loadLogoTask = createObject("roSGNode", "LoadItemsTask2")
+
+    'set inital counts for overhang before content is loaded.
+    m.loadItemsTask.totalRecordCount = 0
+
+    m.spinner.visible = true
+
+    'Get reset folder setting
+    m.resetGrid = get_user_setting("itemgrid.reset") = "true"
+
+    'Check if device has voice remote
+    devinfo = CreateObject("roDeviceInfo")
+
+    'Hide voice search if device does not have voice remote
+    if devinfo.HasFeature("voice_remote") = false
+        m.micButton.visible = false
+        m.micButtonText.visible = false
+    end if
+end sub
+
+sub OnScreenHidden()
+    if not m.overhang.isVisible
+        m.overhang.disableMoveAnimation = true
+        m.overhang.isVisible = true
+        m.overhang.disableMoveAnimation = false
+    end if
+end sub
+
+sub OnScreenShown()
+    m.overhang.isVisible = false
+
+    if m.top.lastFocus <> invalid
+        m.top.lastFocus.setFocus(true)
+    else
+        m.top.setFocus(true)
+    end if
+end sub
+
+'
+'Load initial set of Data
+sub loadInitialItems()
+    m.loadItemsTask.control = "stop"
+    m.spinner.visible = true
+
+    if m.top.parentItem.json.Type = "CollectionFolder"
+        m.top.HomeLibraryItem = m.top.parentItem.Id
+    end if
+
+    if m.top.parentItem.backdropUrl <> invalid
+        SetBackground(m.top.parentItem.backdropUrl)
+    else
+        SetBackground("")
+    end if
+
+    m.sortField = get_user_setting("display." + m.top.parentItem.Id + ".sortField")
+    sortAscendingStr = get_user_setting("display." + m.top.parentItem.Id + ".sortAscending")
+    m.filter = get_user_setting("display." + m.top.parentItem.Id + ".filter")
+    m.view = get_user_setting("display." + m.top.parentItem.Id + ".landing")
+
+    if not isValid(m.sortField) then m.sortField = "SortName"
+    if not isValid(m.filter) then m.filter = "All"
+    if not isValid(m.view) then m.view = "Movies"
+
+    if sortAscendingStr = invalid or sortAscendingStr = "true"
+        m.sortAscending = true
+    else
+        m.sortAscending = false
+    end if
+
+    if m.top.parentItem.json.type = "Studio"
+        m.loadItemsTask.studioIds = m.top.parentItem.id
+        m.loadItemsTask.itemId = m.top.parentItem.parentFolder
+        m.loadItemsTask.genreIds = ""
+    else if m.top.parentItem.json.type = "Genre"
+        m.loadItemsTask.genreIds = m.top.parentItem.id
+        m.loadItemsTask.itemId = m.top.parentItem.parentFolder
+        m.loadItemsTask.studioIds = ""
+    else if m.view = "Movies" or m.options.view = "Movies"
+        m.loadItemsTask.studioIds = ""
+        m.loadItemsTask.genreIds = ""
+    else
+        m.loadItemsTask.itemId = m.top.parentItem.Id
+    end if
+
+    m.loadItemsTask.nameStartsWith = m.top.alphaSelected
+    m.loadItemsTask.searchTerm = m.voiceBox.text
+    m.emptyText.visible = false
+    m.loadItemsTask.sortField = m.sortField
+    m.loadItemsTask.sortAscending = m.sortAscending
+    m.loadItemsTask.filter = m.filter
+    m.loadItemsTask.startIndex = 0
+
+    ' Load Item Types
+    if getCollectionType() = "movies"
+        m.loadItemsTask.itemType = "Movie"
+        m.loadItemsTask.itemId = m.top.parentItem.Id
+    end if
+
+    ' By default we load movies
+    m.loadItemsTask.studioIds = ""
+    m.loadItemsTask.view = "Movies"
+    m.itemGrid.translation = "[96, 650]"
+    m.itemGrid.numRows = "2"
+    m.selectedMovieOverview.visible = true
+    m.infoGroup.visible = true
+
+    if m.options.view = "Studios" or m.view = "Studios"
+        m.itemGrid.translation = "[96, 60]"
+        m.itemGrid.numRows = "3"
+        m.loadItemsTask.view = "Networks"
+        m.top.imageDisplayMode = "scaleToFit"
+        m.selectedMovieOverview.visible = false
+        m.infoGroup.visible = false
+    else if m.options.view = "Genres" or m.view = "Genres"
+        m.loadItemsTask.StudioIds = m.top.parentItem.Id
+        m.loadItemsTask.view = "Genres"
+        m.movieLogo.visible = false
+        m.selectedMovieName.visible = false
+        m.selectedMovieOverview.visible = false
+        m.infoGroup.visible = false
+    end if
+
+    m.loadItemsTask.observeField("content", "ItemDataLoaded")
+    m.spinner.visible = true
+    m.loadItemsTask.control = "RUN"
+    SetUpOptions()
+end sub
+
+' Set Movies view, sort, and filter options
+sub setMoviesOptions(options)
+
+    options.views = [
+        { "Title": tr("Movies"), "Name": "Movies" },
+        { "Title": tr("Studios"), "Name": "Studios" },
+        { "Title": tr("Genres"), "Name": "Genres" }
+    ]
+
+    if m.top.parentItem.json.type = "Genre"
+        options.views = [
+            { "Title": tr("Movies"), "Name": "Movies" }
+        ]
+    end if
+
+    options.sort = [
+        { "Title": tr("TITLE"), "Name": "SortName" },
+        { "Title": tr("IMDB_RATING"), "Name": "CommunityRating" },
+        { "Title": tr("CRITIC_RATING"), "Name": "CriticRating" },
+        { "Title": tr("DATE_ADDED"), "Name": "DateCreated" },
+        { "Title": tr("DATE_PLAYED"), "Name": "DatePlayed" },
+        { "Title": tr("OFFICIAL_RATING"), "Name": "OfficialRating" },
+        { "Title": tr("PLAY_COUNT"), "Name": "PlayCount" },
+        { "Title": tr("RELEASE_DATE"), "Name": "PremiereDate" },
+        { "Title": tr("RUNTIME"), "Name": "Runtime" }
+    ]
+
+    options.filter = [
+        { "Title": tr("All"), "Name": "All" },
+        { "Title": tr("Favorites"), "Name": "Favorites" }
+    ]
+
+    if m.options.view = "Genres" or m.view = "Genres"
+        options.sort = []
+        options.filter = []
+    end if
+
+    if m.options.view = "Studios" or m.view = "Studios"
+        options.sort = [
+            { "Title": tr("TITLE"), "Name": "SortName" },
+            { "Title": tr("DATE_ADDED"), "Name": "DateCreated" },
+        ]
+    end if
+end sub
+
+' Return parent collection type
+function getCollectionType() as string
+    if m.top.parentItem.collectionType = invalid
+        return m.top.parentItem.Type
+    else
+        return m.top.parentItem.CollectionType
+    end if
+end function
+
+' Search string array for search value. Return if it's found
+function inStringArray(array, searchValue) as boolean
+    for each item in array
+        if lcase(item) = lcase(searchValue) then return true
+    end for
+    return false
+end function
+
+' Data to display when options button selected
+sub SetUpOptions()
+    options = {}
+    options.filter = []
+    options.favorite = []
+
+    setMoviesOptions(options)
+
+    ' Set selected view option
+    for each o in options.views
+        if o.Name = m.view
+            o.Selected = true
+            o.Ascending = m.sortAscending
+            m.options.view = o.Name
+        end if
+    end for
+
+    ' Set selected sort option
+    for each o in options.sort
+        if o.Name = m.sortField
+            o.Selected = true
+            o.Ascending = m.sortAscending
+            m.options.sortField = o.Name
+        end if
+    end for
+
+    ' Set selected filter option
+    for each o in options.filter
+        if o.Name = m.filter
+            o.Selected = true
+            m.options.filter = o.Name
+        end if
+    end for
+
+    m.options.options = options
+end sub
+
+'
+' Logo Image Loaded Event Handler
+sub LogoImageLoaded(msg)
+    data = msg.GetData()
+    m.loadLogoTask.unobserveField("content")
+    m.loadLogoTask.content = []
+
+    if data.Count() > 0
+        m.movieLogo.uri = data[0]
+        m.movieLogo.visible = true
+    else
+        m.selectedMovieName.visible = true
+    end if
+end sub
+
+'
+'Handle loaded data, and add to Grid
+sub ItemDataLoaded(msg)
+    m.top.alphaActive = false
+    itemData = msg.GetData()
+    m.loadItemsTask.unobserveField("content")
+    m.loadItemsTask.content = []
+
+    if itemData = invalid
+        m.Loading = false
+        return
+    end if
+
+    if m.loadItemsTask.view = "Genres"
+        ' Reset genre list data
+        m.genreData.removeChildren(m.genreData.getChildren(-1, 0))
+
+        for each item in itemData
+            m.genreData.appendChild(item)
+        end for
+
+        m.itemGrid.opacity = "0"
+        m.genreList.opacity = "1"
+
+        m.itemGrid.setFocus(false)
+        m.genreList.setFocus(true)
+
+        m.loading = false
+        m.spinner.visible = false
+        return
+    end if
+
+    m.itemGrid.opacity = "1"
+    m.genreList.opacity = "0"
+
+    m.itemGrid.setFocus(true)
+    m.genreList.setFocus(false)
+
+    for each item in itemData
+        m.data.appendChild(item)
+    end for
+
+    'Update the stored counts
+    m.loadedItems = m.itemGrid.content.getChildCount()
+    m.loadedRows = m.loadedItems / m.itemGrid.numColumns
+    m.Loading = false
+    'If there are no items to display, show message
+    if m.loadedItems = 0
+        m.emptyText.text = tr("NO_ITEMS").Replace("%1", m.top.parentItem.Type)
+        m.emptyText.visible = true
+    end if
+
+    m.spinner.visible = false
+end sub
+
+'
+'Set Selected Movie Name
+sub SetName(movieName as string)
+    m.selectedMovieName.text = movieName
+end sub
+
+'
+'Set Selected Movie Overview
+sub SetOverview(movieOverview as string)
+    m.selectedMovieOverview.text = movieOverview
+end sub
+
+'
+'Set Selected Movie OfficialRating
+sub SetOfficialRating(movieOfficialRating as string)
+    m.selectedMovieOfficialRating.text = movieOfficialRating
+end sub
+
+'
+'Set Selected Movie ProductionYear
+sub SetProductionYear(movieProductionYear)
+    m.selectedMovieProductionYear.text = movieProductionYear
+end sub
+
+'
+'Set Background Image
+sub SetBackground(backgroundUri as string)
+    if backgroundUri = ""
+        m.backdrop.opacity = 0
+    end if
+
+    'If a new image is being loaded, or transitioned to, store URL to load next
+    if m.swapAnimation.state <> "stopped" or m.newBackdrop.loadStatus = "loading"
+        m.queuedBGUri = backgroundUri
+        return
+    end if
+
+    m.newBackdrop.uri = backgroundUri
+end sub
+
+'
+'Handle new item being focused
+sub onItemFocused()
+    focusedRow = m.itemGrid.currFocusRow
+
+    itemInt = m.itemGrid.itemFocused
+
+    ' If no selected item, set background to parent backdrop
+    if itemInt = -1
+        return
+    end if
+
+    m.movieLogo.visible = false
+    m.selectedMovieName.visible = false
+
+    ' Load more data if focus is within last 5 rows, and there are more items to load
+    if focusedRow >= m.loadedRows - 5 and m.loadeditems < m.loadItemsTask.totalRecordCount
+        loadMoreData()
+    end if
+
+    m.selectedFavoriteItem = getItemFocused()
+    m.communityRatingGroup.visible = false
+    m.criticRatingGroup.visible = false
+
+    if m.options.view = "Studios" or m.view = "Studios"
+        return
+    end if
+
+    itemData = m.selectedFavoriteItem.json
+
+    if isValid(itemData.communityRating)
+        setFieldText("communityRating", int(itemData.communityRating * 10) / 10)
+        m.communityRatingGroup.visible = true
+    end if
+
+    if isValid(itemData.CriticRating)
+        setFieldText("criticRatingLabel", itemData.criticRating)
+
+        tomato = "pkg:/images/rotten.png"
+
+        if itemData.CriticRating > 60
+            tomato = "pkg:/images/fresh.png"
+        end if
+
+        m.criticRatingIcon.uri = tomato
+        m.criticRatingGroup.visible = true
+    end if
+
+    if isValid(itemData.Name)
+        SetName(itemData.Name)
+    else
+        SetName("")
+    end if
+
+    if isValid(itemData.Overview)
+        SetOverview(itemData.Overview)
+    else
+        SetOverview("")
+    end if
+
+    if isValid(itemData.ProductionYear)
+        SetProductionYear(str(itemData.ProductionYear))
+    else
+        SetProductionYear("")
+    end if
+
+    if type(itemData.RunTimeTicks) = "LongInteger"
+        setFieldText("runtime", stri(getRuntime(itemData.RunTimeTicks)) + " mins")
+    else
+        setFieldText("runtime", "")
+    end if
+
+    if isValid(itemData.OfficialRating)
+        SetOfficialRating(itemData.OfficialRating)
+    else
+        SetOfficialRating("")
+    end if
+
+    m.loadLogoTask.itemId = itemData.id
+    m.loadLogoTask.itemType = "LogoImage"
+    m.loadLogoTask.observeField("content", "LogoImageLoaded")
+    m.loadLogoTask.control = "RUN"
+
+    ' Set Background to item backdrop
+    SetBackground(m.selectedFavoriteItem.backdropUrl)
+end sub
+
+function getRuntime(runTimeTicks) as integer
+    return round(runTimeTicks / 600000000.0)
+end function
+
+function round(f as float) as integer
+    ' BrightScript only has a "floor" round
+    ' This compares floor to floor + 1 to find which is closer
+    m = int(f)
+    n = m + 1
+    x = abs(f - m)
+    y = abs(f - n)
+    if y > x
+        return m
+    else
+        return n
+    end if
+end function
+
+sub setFieldText(field, value)
+    node = m.top.findNode(field)
+    if node = invalid or value = invalid then return
+
+    ' Handle non strings... Which _shouldn't_ happen, but hey
+    if type(value) = "roInt" or type(value) = "Integer"
+        value = str(value)
+    else if type(value) = "roFloat" or type(value) = "Float"
+        value = str(value)
+    else if type(value) <> "roString" and type(value) <> "String"
+        value = ""
+    end if
+
+    node.text = value
+end sub
+
+'
+'When Image Loading Status changes
+sub newBGLoaded()
+    'If image load was sucessful, start the fade swap
+    if m.newBackdrop.loadStatus = "ready"
+        m.swapAnimation.control = "start"
+    end if
+end sub
+
+'
+'Swap Complete
+sub swapDone()
+    if m.swapAnimation.state = "stopped"
+        'Set main BG node image and hide transitioning node
+        m.backdrop.uri = m.newBackdrop.uri
+        m.backdrop.opacity = 1
+        m.newBackdrop.opacity = 0
+
+        'If there is another one to load
+        if m.newBackdrop.uri <> m.queuedBGUri and m.queuedBGUri <> ""
+            SetBackground(m.queuedBGUri)
+            m.queuedBGUri = ""
+        end if
+    end if
+end sub
+
+'
+'Load next set of items
+sub loadMoreData()
+    m.spinner.visible = true
+    if m.Loading = true then return
+    m.Loading = true
+    m.loadItemsTask.startIndex = m.loadedItems
+    m.loadItemsTask.observeField("content", "ItemDataLoaded")
+    m.loadItemsTask.control = "RUN"
+end sub
+
+'
+'Item Selected
+sub onItemSelected()
+    m.top.selectedItem = m.itemGrid.content.getChild(m.itemGrid.itemSelected)
+end sub
+
+'
+'Returns Focused Item
+function getItemFocused()
+    return m.itemGrid.content.getChild(m.itemGrid.itemFocused)
+end function
+
+'
+'Genre Item Selected
+sub onGenreItemSelected()
+    m.top.selectedItem = m.genreList.content.getChild(m.genreList.rowItemSelected[0]).getChild(m.genreList.rowItemSelected[1])
+end sub
+
+sub onItemalphaSelected()
+    if m.top.alphaSelected <> ""
+        m.loadedRows = 0
+        m.loadedItems = 0
+
+        m.data = CreateObject("roSGNode", "ContentNode")
+        m.itemGrid.content = m.data
+
+        m.genreData = CreateObject("roSGNode", "ContentNode")
+        m.genreList.content = m.genreData
+
+        m.loadItemsTask.searchTerm = ""
+        m.VoiceBox.text = ""
+        m.loadItemsTask.nameStartsWith = m.alpha.itemAlphaSelected
+        m.spinner.visible = true
+        loadInitialItems()
+    end if
+end sub
+
+sub onvoiceFilter()
+    if m.VoiceBox.text <> ""
+        m.loadedRows = 0
+        m.loadedItems = 0
+        m.data = CreateObject("roSGNode", "ContentNode")
+        m.itemGrid.content = m.data
+        m.top.alphaSelected = ""
+        m.loadItemsTask.NameStartsWith = " "
+        m.loadItemsTask.searchTerm = m.voiceBox.text
+        m.loadItemsTask.recursive = true
+        m.spinner.visible = true
+        loadInitialItems()
+    end if
+end sub
+
+
+'
+'Check if options updated and any reloading required
+sub optionsClosed()
+    reload = false
+
+    if m.options.sortField <> m.sortField or m.options.sortAscending <> m.sortAscending
+        m.sortField = m.options.sortField
+        m.sortAscending = m.options.sortAscending
+        reload = true
+
+        sortAscendingStr = "true"
+
+        'Store sort settings
+        if not m.sortAscending
+            sortAscendingStr = "false"
+        end if
+
+        set_user_setting("display." + m.top.parentItem.Id + ".sortField", m.sortField)
+        set_user_setting("display." + m.top.parentItem.Id + ".sortAscending", sortAscendingStr)
+    end if
+
+    if m.options.filter <> m.filter
+        m.filter = m.options.filter
+        reload = true
+        set_user_setting("display." + m.top.parentItem.Id + ".filter", m.options.filter)
+    end if
+
+    m.view = get_user_setting("display." + m.top.parentItem.Id + ".landing")
+
+    if m.options.view <> m.view
+        m.view = m.options.view
+        set_user_setting("display." + m.top.parentItem.Id + ".landing", m.view)
+
+        ' Reset any filtering or search terms
+        m.top.alphaSelected = ""
+        m.loadItemsTask.NameStartsWith = " "
+        m.loadItemsTask.searchTerm = ""
+        m.filter = "All"
+        m.sortField = "SortName"
+        m.sortAscending = true
+
+        ' Reset view to defaults
+        set_user_setting("display." + m.top.parentItem.Id + ".sortField", m.sortField)
+        set_user_setting("display." + m.top.parentItem.Id + ".sortAscending", "true")
+        set_user_setting("display." + m.top.parentItem.Id + ".filter", m.filter)
+
+        reload = true
+    end if
+
+    if reload
+        m.loadedRows = 0
+        m.loadedItems = 0
+        m.data = CreateObject("roSGNode", "ContentNode")
+        m.itemGrid.content = m.data
+        loadInitialItems()
+    end if
+
+    m.itemGrid.setFocus(m.itemGrid.opacity = 1)
+    m.genreList.setFocus(m.genreList.opacity = 1)
+end sub
+
+sub onChannelSelected(msg)
+    node = msg.getRoSGNode()
+    m.top.lastFocus = lastFocusedChild(node)
+    if node.watchChannel <> invalid
+        ' Clone the node when it's reused/update in the TimeGrid it doesn't automatically start playing
+        m.top.selectedItem = node.watchChannel.clone(false)
+    end if
+end sub
+
+function onKeyEvent(key as string, press as boolean) as boolean
+    if not press then return false
+
+    if key = "left" and m.voiceBox.isinFocusChain()
+        m.itemGrid.setFocus(m.itemGrid.opacity = 1)
+        m.genreList.setFocus(m.genreList.opacity = 1)
+        m.voiceBox.setFocus(false)
+    end if
+
+    if key = "options"
+        if m.options.visible = true
+            m.options.visible = false
+            m.top.removeChild(m.options)
+            optionsClosed()
+        else
+
+            itemSelected = m.selectedFavoriteItem
+            if itemSelected <> invalid
+                m.options.selectedFavoriteItem = itemSelected
+            end if
+
+            m.options.visible = true
+            m.top.appendChild(m.options)
+            m.options.setFocus(true)
+        end if
+        return true
+    else if key = "back"
+        if m.options.visible = true
+            m.options.visible = false
+            optionsClosed()
+            return true
+        else
+            m.global.sceneManager.callfunc("popScene")
+            m.loadItemsTask.control = "stop"
+            return true
+        end if
+    else if key = "play" or key = "OK"
+
+        itemToPlay = getItemFocused()
+
+        if itemToPlay <> invalid and (itemToPlay.type = "Movie" or itemToPlay.type = "Episode")
+            m.top.quickPlayNode = itemToPlay
+            return true
+        end if
+    else if key = "left"
+        if m.itemGrid.isinFocusChain()
+            m.top.alphaActive = true
+            m.itemGrid.setFocus(false)
+            alpha = m.alpha.getChild(0).findNode("Alphamenu")
+            alpha.setFocus(true)
+            return true
+        else if m.genreList.isinFocusChain()
+            m.top.alphaActive = true
+            m.genreList.setFocus(false)
+            alpha = m.alpha.getChild(0).findNode("Alphamenu")
+            alpha.setFocus(true)
+            return true
+        end if
+
+    else if key = "right" and m.Alpha.isinFocusChain()
+        m.top.alphaActive = false
+        m.Alpha.setFocus(false)
+        m.Alpha.visible = true
+
+        m.itemGrid.setFocus(m.itemGrid.opacity = 1)
+        m.genreList.setFocus(m.genreList.opacity = 1)
+
+        return true
+
+    else if key = "replay" and m.itemGrid.isinFocusChain()
+        if m.resetGrid = true
+            m.itemGrid.animateToItem = 0
+        else
+            m.itemGrid.jumpToItem = 0
+        end if
+
+    else if key = "replay" and m.genreList.isinFocusChain()
+        if m.resetGrid = true
+            m.genreList.animateToItem = 0
+        else
+            m.genreList.jumpToItem = 0
+        end if
+        return true
+    end if
+
+    if key = "replay"
+        m.spinner.visible = true
+        m.loadItemsTask.searchTerm = ""
+        m.loadItemsTask.nameStartsWith = ""
+        m.voiceBox.text = ""
+        m.top.alphaSelected = ""
+        m.loadItemsTask.filter = "All"
+        m.filter = "All"
+        m.data = CreateObject("roSGNode", "ContentNode")
+        m.itemGrid.content = m.data
+        loadInitialItems()
+        return true
+    end if
+
+    return false
+end function

components/ItemGrid/MovieLibraryView.xml

@@ -0,0 +1,65 @@
+<?xml version="1.0" encoding="utf-8" ?>
+<component name="MovieLibraryView" extends="JFScreen">
+  <children>
+    <Rectangle id="screenSaverBackground" width="1920" height="1080" color="#000000" />
+
+    <VoiceTextEditBox id="VoiceBox" visible="true" width = "40" translation = "[52, 120]" />
+    <Rectangle id="VoiceBoxCover" height="240" width="100" color="0x000000ff" translation = "[25, 75]" />
+
+    <maskGroup translation="[820, 0]" id="backgroundMask" maskUri="pkg:/images/backgroundmask.png" maskSize="[1220,700]">
+      <poster id="backdrop" loadDisplayMode="scaleToFill" width="1100" height="700" opacity="1" />
+      <poster id="backdropTransition" loadDisplayMode="scaleToFill" width="1100" height="700" opacity="1" />
+    </maskGroup>
+
+    <Label id="selectedMovieName" visible="false" translation="[120, 40]" wrap="true" font="font:LargeBoldSystemFont" width="850" height="196" horizAlign="left" vertAlign="center" />
+    <Poster id="movieLogo" visible="false" translation="[120, 40]" loadDisplayMode="scaleToFit" width="384" height="196" />
+
+    <LayoutGroup layoutDirection="horiz" translation="[120, 270]" itemSpacings="[30]" id="infoGroup">
+      <Label id="selectedMovieProductionYear" font="font:SmallestSystemFont" />
+      <Label id="runtime" font="font:SmallestSystemFont" />
+      <Label id="selectedMovieOfficialRating" font="font:SmallestSystemFont" />
+
+      <LayoutGroup id="communityRatingGroup" visible="false" layoutDirection="horiz" itemSpacings="[-5]">
+        <Poster id="star" uri="pkg:/images/sharp_star_white_18dp.png" height="28" width="28" blendColor="#00a4dcFF" />
+        <Label id="communityRating" font="font:SmallestSystemFont" />
+      </LayoutGroup>
+
+      <LayoutGroup layoutDirection="horiz" id="criticRatingGroup">
+        <Poster id="criticRatingIcon" height="28" width="28" />
+        <Label id="criticRatingLabel" font="font:SmallestSystemFont" />
+      </LayoutGroup>
+    </LayoutGroup>
+
+    <Label id="selectedMovieOverview" font="font:SmallestSystemFont" translation="[120, 360]" wrap="true" lineSpacing="20" maxLines="5" width="850" ellipsisText="..." />
+
+    <MarkupGrid id="itemGrid" itemComponentName="GridItemSmall" numColumns="7" numRows="2" vertFocusAnimationStyle="fixed" itemSize="[230, 310]" itemSpacing="[20, 20]" />
+    <RowList opacity="0" id="genrelist" translation="[120, 60]" showRowLabel="true" itemComponentName="GridItemSmall" numColumns="1" numRows="3" vertFocusAnimationStyle="fixed" itemSize = "[1900, 360]" rowItemSize="[ [230, 320] ]" rowItemSpacing="[ [20, 0] ]" itemSpacing="[0, 60]" />
+
+    <Label id="micButtonText" font="font:SmallSystemFont" visible="false" />
+    <Button id = "micButton"  maxWidth = "20" translation = "[20, 120]" iconUri = "pkg:/images/icons/mic_icon.png"/>
+    <Label translation="[0,540]" id="emptyText" font="font:LargeSystemFont" width="1910" horizAlign="center" vertAlign="center" height="64" visible="false" />
+    <ItemGridOptions id="options" visible="false" />
+    <Spinner id="spinner" translation="[900, 450]" />
+    <Animation id="backroundSwapAnimation" duration="1" repeat="false" easeFunction="linear">
+      <FloatFieldInterpolator id = "fadeinLoading" key="[0.0, 1.0]" keyValue="[ 0.00, 1.00 ]" fieldToInterp="backdropTransition.opacity" />
+      <FloatFieldInterpolator id = "fadeoutLoaded" key="[0.0, 1.0]" keyValue="[ 1.00, 0.00 ]" fieldToInterp="backdrop.opacity" />
+    </Animation>
+    <Alpha id="AlphaMenu" />
+  </children>
+  <interface>
+    <field id="HomeLibraryItem" type="string"/>
+    <field id="parentItem" type="node" onChange="loadInitialItems" />
+    <field id="selectedItem" type="node" alwaysNotify="true" />
+    <field id="quickPlayNode" type="node" alwaysNotify="true" />
+    <field id="imageDisplayMode" type="string" value="scaleToZoom" />
+    <field id="AlphaSelected" type="string" alias="AlphaMenu.itemAlphaSelected" alwaysNotify="true" onChange="onItemAlphaSelected" />
+    <field id="alphaActive" type="boolean" value="false" />
+    <field id="jumpToItem" type="integer" value="" />
+  </interface>
+  <script type="text/brightscript" uri="pkg:/source/utils/misc.brs" />
+  <script type="text/brightscript" uri="pkg:/source/utils/config.brs" />
+  <script type="text/brightscript" uri="pkg:/source/api/baserequest.brs" />
+  <script type="text/brightscript" uri="pkg:/source/api/Image.brs" />
+  <script type="text/brightscript" uri="pkg:/source/utils/deviceCapabilities.brs" />
+  <script type="text/brightscript" uri="MovieLibraryView.brs" />
+</component>

components/data/MovieData.brs

@@ -8,12 +8,14 @@ sub setFields()
     m.top.watched = json.UserData.played
     m.top.Type = "Movie"
 
-    if json.MediaSourceCount <> invalid and json.MediaSourceCount > 1
+    if isValid(json.MediaSourceCount) and json.MediaSourceCount > 1
+        if isValid(json.MediaSources)
             m.top.mediaSources = []
             for each source in json.MediaSources
                 m.top.mediaSources.push(source)
             end for
         end if
+    end if
 
     if json.ProductionYear <> invalid
         m.top.SubTitle = json.ProductionYear
@@ -49,10 +51,12 @@ sub setPoster()
         end if
 
         ' Add Backdrop Image
+        if m.top.json.BackdropImageTags <> invalid
             if m.top.json.BackdropImageTags[0] <> invalid
                 imgParams = { "maxHeight": 720, "maxWidth": 1280 }
                 m.top.backdropURL = ImageURL(m.top.json.id, "Backdrop", imgParams)
             end if
+        end if
 
     end if
 end sub

components/data/MovieData.xml

@@ -12,4 +12,5 @@
   <script type="text/brightscript" uri="pkg:/source/api/Image.brs" />
   <script type="text/brightscript" uri="pkg:/source/api/baserequest.brs" />
   <script type="text/brightscript" uri="pkg:/source/utils/config.brs" />
+  <script type="text/brightscript" uri="pkg:/source/utils/misc.brs" />
 </component>

components/music/NowPlaying.brs

@@ -408,7 +408,7 @@ sub onMetaDataLoaded()
     if data <> invalid and data.count() > 0
 
         ' Use metadata to load backdrop image
-        if isvalid(data.json)
+        if isValid(data.json)
             if isValid(data.json.ArtistItems)
                 if data.json.ArtistItems.count() > 0
                     if isValid(data.json.ArtistItems[0].id)

source/Main.brs

@@ -103,8 +103,20 @@ sub Main (args as dynamic) as void
         else if isNodeEvent(msg, "selectedItem")
             ' If you select a library from ANYWHERE, follow this flow
             selectedItem = msg.getData()
+
             m.selectedItemType = selectedItem.type
-            if selectedItem.type = "CollectionFolder" or selectedItem.type = "UserView" or selectedItem.type = "Folder" or selectedItem.type = "Channel" or selectedItem.type = "Boxset"
+            '
+            if selectedItem.type = "CollectionFolder"
+                if selectedItem.collectionType = "movies"
+                    group = CreateMovieLibraryView(selectedItem)
+                else
+                    group = CreateItemGrid(selectedItem)
+                end if
+                sceneManager.callFunc("pushScene", group)
+            else if selectedItem.type = "Folder" and selectedItem.json.type = "Genre"
+                group = CreateMovieLibraryView(selectedItem)
+                sceneManager.callFunc("pushScene", group)
+            else if selectedItem.type = "UserView" or selectedItem.type = "Folder" or selectedItem.type = "Channel" or selectedItem.type = "Boxset"
                 group = CreateItemGrid(selectedItem)
                 sceneManager.callFunc("pushScene", group)
             else if selectedItem.type = "Episode"

source/ShowScenes.brs

@@ -475,6 +475,14 @@ function CreateItemGrid(libraryItem)
     return group
 end function
 
+function CreateMovieLibraryView(libraryItem)
+    group = CreateObject("roSGNode", "MovieLibraryView")
+    group.parentItem = libraryItem
+    group.optionsAvailable = true
+    group.observeField("selectedItem", m.port)
+    return group
+end function
+
 function CreateSearchPage()
     ' Search + Results Page
     group = CreateObject("roSGNode", "searchResults")